; $VER: Startup-Sequence_HardDrive 47.16 (18.10.2021)
; Startup-Sequence for hard drive systems
;SET ECHO ON
Version exec.library version 47 >NIL:
If Warn
  LoadModule L:System-Startup ROMUPDATE
Else
  Version strap version 47 >NIL:
  If Warn
    LoadModule DOWNGRADE L:Ram-Handler L:Shell-Seg L:System-Startup Libs:dos.library Libs:gadtools.library Libs:graphics.library >NIL:
  EndIf
EndIf
SetPatch >NIL:

;------------------- CPU CheckInstall Section ------------------------

FailAt 31
CPU CHECKINSTALL

SET temp1 $RC

If VAL $temp1 EQ 30
  ECHO ""
  ASK "Press the RETURN key to resume booting into a restricted system."
  Execute S:Startup-failsafe
  QUIT
EndIf

If VAL $temp1 EQ 5
  ECHO ""
  ASK "Press the RETURN key to resume booting."
EndIf

UNSET temp1

;---------------- End of CPU CheckInstall Section --------------------

FailAt 10
Version >NIL:

Assign >nil: EXISTS DF0:
If not warn
  AddBuffers DF0: 15 >NIL:
EndIf

If EXISTS ENVARC:
   MakeLink RAM:ENV to ENVARC: FORCE
Else
   MakeDir RAM:ENV
Endif
MakeDir RAM:T RAM:Clipboards

Resident C:Assign PURE

Assign ENV: RAM:ENV
Assign T: RAM:T
Assign CLIPS: RAM:Clipboards
Assign REXX: S:

FailAt 21
Assign PRINTERS: DEVS:Printers
Assign KEYMAPS: DEVS:Keymaps
Assign LOCALE: SYS:Locale
Assign LIBS: SYS:Classes ADD
Assign HELP: LOCALE:Help DEFER

BindDrivers
Mount DEVS:DOSDrivers/~(#?.info)

LoadMonDrvs >NIL:

FailAt 10
SetEnv Language "english"
SetEnv Workbench $Workbench
SetEnv Kickstart $Kickstart
UnSet Workbench
UnSet Kickstart

stack 40000

IF EXISTS S:User-Startup
  Execute S:User-Startup
EndIF

AddDataTypes REFRESH QUIET
IPrefs
ConClip

If EXISTS SYS:System/RexxMast
  SYS:System/RexxMast >NIL:
EndIF

Path C: SYS:Utilities SYS:Rexxc SYS:System S: SYS:Prefs SYS:Tools SYS:Tools/Commodities

MakeLink RAM:Disk.info TO ENVARC:Sys/def_RAM.info SOFT

LoadWB
EndCLI >NIL:


---------------------------------------------------------------------------------------------------------------------------------------------------------


; $Date: 2020-09-05 12:00:00 $ $Revision: 47.1 $
; User-startup for hard drive systems
;
;+-------------------------------------------------------------------+
;| This is the User-startup script. Here you can write down the      |
;| names of the programs you wish to have automatically run every    |
;| time your machine boots.                                          |
;|                                                                   |
;| Lines starting with the ";" symbol are ignored and used as        |
;| comments.                                                         | 
;+-------------------------------------------------------------------+
;BEGIN Picasso96
Assign Picasso96: "System:Storage/Picasso96"
;END Picasso96
;BEGIN MUI
if exists "System:MUI"
   assign MUI: "System:MUI"
   if exists MUI:Libs
      assign add LIBS: MUI:Libs
   endif
   if exists MUI:Locale
      assign add LOCALE: MUI:Locale
   endif
   version >nil: exec.library 39
   if not warn
      if exists MUI:Docs
         if exists HELP:dummy ; do not remove
         endif                ; this entry!
         assign add HELP: MUI:Docs
      endif
   endif
endif
;END MUI
;BEGIN MUI ASL
if exists "System:MUI"
   run <>nil: MUI:PatchASL
endif
;END MUI ASL
;BEGIN XpkMasterPrefs
Run >NIL: XpkMasterPrefs
;END XpkMasterPrefs
;SET ECHO ON
if exists DH2:START
    cd DH2:
    execute START
endif


---------------------------------------------------------------------------------------------------------------------------------------------------------


; START script code wich loads the game (ECS)

CD DH2:FantasyFlyer
WHDLoad FantasyFlyer.slave Preload

; START script code wich loads the game (AGA)

CD DH2:FantasyFlyerAGA
WHDLoad FantasyFlyerAGA.slave Preload