0006504: Hello. I hope you are fine. I’m writing hooping don’t disturb you. I’m making

View Issue Details [ Jump to Notes ]

[ Issue History ] [ Print ]

Project

Tags

No tags attached.

Machine

A500

CPU

68000

CPUSpeed

ChipSet

OCS

GFXCard

None

ChipMem

256 KB

FastMem

0 MB

Workbench

OS 3.2

KickROM

47 - Kick 3.2

KickSoft

None

WHDLoad

19.0beta

imported

yes

Attached Files

Pitfighter.asm (2,090 bytes) 2024-05-29 21:40

	INCDIR	"Include:"
	INCLUDE	whdload.i

_base		SLAVE_HEADER			;ws_Security + ws_ID
		dc.w	7			;ws_Version
		dc.w	WHDLF_NoError|WHDLF_EmulTrap		;ws_flags
		dc.l	$80000			;ws_BaseMemSize
		dc.l	$0			;ws_ExecInstall
		dc.w	_Start-_base		;ws_GameLoader
		dc.w	0			;ws_CurrentDir
		dc.w	0			;ws_DontCache
_keydebug	dc.b	0			;ws_keydebug
_keyexit	dc.b	0			;ws_keyexit = F10

		dc.b	'$VER: Pitfighter HD V1.1 by Bored Seal',0,0

_Start		lea	(_resload,pc),a1
		move.l	a0,(a1)			;save for later using

		move.l	#$400,d0		;load boot and check version
		move.l	#$1600,d1
		clr.l	d2
		bsr	Loader

CheckVer	lea     $400,a0
		move.l  #$1600,d0
		move.l  (_resload,pc),a2
		jsr     (resload_CRC16,a2)

		lea	ver,a3
		move.w	d0,(a3)

		cmp.w   #$73FD,d0
		beq	ChrisBoot
		cmp.w   #$B4AC,d0
		bne	Unsupported

CondorBoot	move.l	#$400,d0
		move.l	#1*$1600,d1
		moveq	#$16,d2
		bsr	Loader

		bra	Patch

ChrisBoot	move.l	#$400,d0
		move.l	#1*$1600,d1
		moveq	#$b,d2
		bsr	Loader

Patch		move.w	#$4ef9,$f76
		pea	Loader
		move.l	(sp)+,$f78

		pea	Patch1
		move.l	(sp)+,$1232

		jmp	$400

Patch1		move.w	#$4ef9,$3a2c
		pea	Loader
		move.l	(sp)+,$3a2e

		pea	Patch2
		move.l	(sp)+,$58ec

		bra	Run2000

Patch2		move.w	#$4ef9,$7ec90
		pea	Patch3
		move.l	(sp)+,$7ec92

		jmp	$7ec78

Patch3		move.w	#$4ef9,$2624
		pea	Loader
		move.l	(sp)+,$2626

		move.l	a3,-(sp)
		lea	ver,a3

		cmp.w   #$73FD,(a3)
		beq	ChrisProt

		move.w	#$4ef9,$22ea		;crack RNC protection
		pea	CondorCrack
		move.l	(sp)+,$22ec
		bra	Run2000

ChrisProt	pea	ChrisCrack
		move.l	(sp)+,$22ec
Run2000		jmp	$2000

CondorCrack	move.w	#$4e71,$e9c8		;fix snoop mode
		jmp	$914c

ChrisCrack	move.w	#$4e71,$e9ae		;fix clr.w $dff000
		jmp	$9136

Loader		MOVEM.L	D0-D7/A0-A6,-(SP)
		MOVEA.L	D0,A0
		MOVE.L	D2,D0
		MULU.W	#$200,D0
		MOVEQ	#1,D2
		cmp.l	#'GOD1',d3
		bne	nodisk2
		moveq	#2,d2
nodisk2		MOVEA.L	(_resload,PC),A6
		JSR	(resload_DiskLoad,A6)
		MOVEM.L	(SP)+,D0-D7/A0-A6
		MOVEQ	#0,D0
		RTS

Unsupported	pea	TDREASON_WRONGVER
		move.l	(_resload),-(a7)
		add.l	#resload_Abort,(a7)
		rts

_resload	dc.l	0			;address of resident loader
ver		dc.w	0

Pitfighter.asm (2,090 bytes) 2024-05-29 21:40

IMG_9644.jpeg (147,504 bytes) 2024-06-05 04:21

IMG_9644.jpeg (147,504 bytes) 2024-06-05 04:21

MeanStreets.asm (4,641 bytes) 2024-06-10 23:23

		INCDIR	"Include:"
		INCLUDE	whdload.i

_base		SLAVE_HEADER			;ws_Security + ws_ID
		dc.w	10			;ws_Version
		dc.w	WHDLF_NoError|WHDLF_ClearMem		;ws_flags
		dc.l	$80000			;ws_BaseMemSize
		dc.l	0			;ws_ExecInstall
		dc.w	_Start-_base		;ws_GameLoader
		dc.w	_dir-_base		;ws_CurrentDir
		dc.w	0			;ws_DontCache
_keydebug	dc.b	0			;ws_keydebug
_keyexit	dc.b	$59			;ws_keyexit = F10
_expmem		dc.l	0
		dc.w	_name-_base		;ws_name
		dc.w	_copy-_base		;ws_copy
		dc.w	_info-_base		;ws_info

_dir		dc.b	"data",0
_name		dc.b	"Mean Streets",0
_copy		dc.b	"1990 US Gold",0
_info		dc.b	"installed & fixed by Bored Seal",10
		dc.b	"V1.2 (17-Feb-2006)",0
		even

_Start		lea	(_resload,pc),a1
		move.l	a0,(a1)			;save for later using
		move.l	a0,a2

		lea	filename,a0
		lea	$200,a1
		move.l	a1,-(sp)
		jsr	(resload_LoadFile,a2)
		move.l	(sp),a0
		jsr	(resload_CRC16,a2)
		move.l	(sp)+,a0

		move.l	d0,-(sp)
		suba.l	a1,a1
		jsr	resload_Relocate(a2)
		move.l	(sp)+,d0

		lea	$100,a0			;snoop mode fix
		move.l	#$fffffffe,(a0)
		move.l	a0,$dff080

		cmp.w	#$c82e,d0
		beq	German
		cmp.w	#$8a,d0
		beq	French
		cmp.w	#$1d99,d0
		bne	Unsupported

English		move.w	#$4e75,$63c8		;BFD access
		move.w	#$4e75,$63e6

		move.w	#$4ef9,$5d8a
		pea	LoadFile
		move.l	(sp)+,$5d8c

		move.w	#$4ef9,$61ca
		pea	SaveGame
		move.l	(sp)+,$61cc

		move.w	#$4ef9,$618c
		pea	LoadGame
		move.l	(sp)+,$618e

		move.w	#$4ef9,$5d4c
		pea	Relocate
		move.l	(sp)+,$5d4e

		move.w	#$4eb9,$678e		;fix keyboard
		pea	KBDelay
		move.l	(sp)+,$6790

		move.w	#$4eb9,$59c0
		pea	Patch_ENG
		move.l	(sp)+,$59c2

		jmp	$200

German		move.w	#$4e75,$642a		;BFD access
		move.w	#$4e75,$6448

		move.w	#$4ef9,$5dec
		pea	LoadFile
		move.l	(sp)+,$5dee

		move.w	#$4ef9,$622c
		pea	SaveGame
		move.l	(sp)+,$622e

		move.w	#$4ef9,$61ee
		pea	LoadGame
		move.l	(sp)+,$61f0

		move.w	#$4ef9,$5dae
		pea	Relocate
		move.l	(sp)+,$5db0

		move.w	#$4eb9,$67f0		;fix keyboard
		pea	KBDelay
		move.l	(sp)+,$67f2

		move.w	#$4eb9,$5a22
		pea	Patch_GER
		move.l	(sp)+,$5a24

		jmp	$200


French		move.w	#$4e75,$6418		;BFD access
		move.w	#$4e75,$6436

		move.w	#$4ef9,$5dda
		pea	LoadFile
		move.l	(sp)+,$5ddc

		move.w	#$4ef9,$621a
		pea	SaveGame
		move.l	(sp)+,$621c

		move.w	#$4ef9,$61dc
		pea	LoadGame
		move.l	(sp)+,$61de

		move.w	#$4ef9,$5d9c
		pea	Relocate
		move.l	(sp)+,$5d9e

		move.w	#$4eb9,$67de		;fix keyboard
		pea	KBDelay
		move.l	(sp)+,$67e0

		move.w	#$4eb9,$5a10
		pea	Patch_FRE
		move.l	(sp)+,$5a12

		jmp	$200

Patch_GER	lea	$5a46,a0

		cmp.l	#$61000102,$c93a	;FRONT.PRG
		bne	go
		move.w	#$6002,$c93a		;manual protection
		jmp	(a6)

Patch_FRE	lea	$5a34,a0

		cmp.l	#$61000102,$ca0a	;FRONT.PRG
		bne	go
		move.w	#$6002,$ca0a		;manual protection
		jmp	(a6)

Patch_ENG	lea	$59e4,a0

		cmp.l	#$61000102,$c8e6	;FRONT.PRG
		bne	go
		move.w	#$6002,$c8e6		;manual protection
;		move.w	#$4e75,$d1b8		;fix snoop bug - disable delays
go		jmp	(a6)

Relocate	LEA	($18,A0),A0
		MOVE.L	(A0)+,D0
		CMPI.W	#$3E9,D0
		BNE.B	ccr1
		MOVE.L	(A0)+,D0
		LSL.L	#2,D0
		LEA	(A0,D0.L),A1
		MOVE.L	(A1)+,D0
		CMPI.W	#$3EC,D0
		BNE.B	ccr0
		ADDQ.W	#8,A1
		MOVE.L	A0,D1
lab1		MOVE.L	(A1)+,D0
		BEQ.B	ccr0
		LEA	(A0,D0.L),A2
		ADD.L	D1,(A2)
		BRA.B	lab1

ccr0		MOVE.W	#0,CCR
		RTS

ccr1		MOVE.W	#1,CCR
		RTS

KBDelay		moveq	#2,d1
BM_1		move.w  d1,-(sp)
		move.b	$dff006,d1	; VPOS
BM_2		cmp.b	$dff006,d1
		beq	BM_2
		move.w	(sp)+,d1
		dbf	d1,BM_1
		clr.b	$bfec01
		rts

LoadGame	lea	$700f8,a0		;correct adress
		movem.l	d0-d2/a0-a2,-(sp)
		sub.l	#$6d5,d0		;substract offset
		mulu.w	#$200,d0
		move.l	#$200,d1		;size of savegame
		moveq	#1,d2
		move.l	(_resload,pc),a2
		jsr	(resload_DiskLoad,a2)
		movem.l	(sp)+,d0-d2/a0-a2
		rts

SaveGame	movem.l	d0-d2/a0-a2,-(sp)
		sub.l	#$6d5,d0		;substract offset
		mulu.w	#$200,d0
		move.l	d0,d1
		move.l	#$200,d0
		move.l	a0,a1
		lea	savedisk,a0
		move.l	(_resload,pc),a2
		jsr	(resload_SaveFileOffset,a2)
		movem.l	(sp)+,d0-d2/a0-a2
		rts

LoadFile	movem.l d1/a0-a2,-(sp)
		move.l	(a0)+,a1		;destination
		bsr	FixName			;correct filename
		move.l	(_resload,pc),a2
		jsr	(resload_LoadFile,a2)
		movem.l	(sp)+,d1/a0-a2		;result: d0=filesize
		rts

FixName		cmp.w	#'A:',(a0)
		bne	next
		lea	3(a0),a0		;skip "A:\" path
next		cmp.b	#$5c,(a0)
		bne	fixpath
		lea	1(a0),a0		;skip "\" path

fixpath		move.l	a0,a2			;save filename adr
replace		tst.b	(a2)			;end of filename string?
		beq	done
		cmp.b	#$5c,(a2)
		bne	nextletter
		move.b	#'/',(a2)		;insert correct "/" path
nextletter	lea	1(a2),a2
		bra	replace
done		rts

Unsupported	pea	TDREASON_WRONGVER
		move.l	(_resload),-(a7)
		add.l	#resload_Abort,(a7)
		rts

_resload	dc.l	0
filename	dc.b	"boot.prg",0
savedisk	dc.b	"Disk.1",0

MeanStreets.asm (4,641 bytes) 2024-06-10 23:23

Relationships

Relationships

Notes
note ~0013729 Wepl (manager) 2024-05-29 09:53	There are many installs without source. I have all the sources from Bored Seal. I can share this source if you have interest to improve it. Please do not ask for sources just for collection reasons.

note ~0013730 Alex C (reporter) 2024-05-29 15:45	Hello again. Yes in fact the sources like this one my purpose is I’m studying with help of others from eab forum how to improve.remove bugs, add more things. If you can send to check would be fine. I was an Amiga FAN before bankruptcy and I do developments, but now that I have time I’m returning to learn more and improve. For example now I’m removing bugs from creatures and ork, the sources in whdload have bugs and I’m removing them. If you can send would be fine. Thank you

note ~0013731 Alex C (reporter) 2024-05-29 15:54	Another note. As I said I’m fixing some bugs in some sources. What is the procedure to upload a bug fixed source? Just to know. Just in case to have in my mind. Thank you

note ~0013733 Wepl (manager) 2024-05-29 21:43	Source attached. Prefered would be an updated install package which includes new Slave and updated ReadMe describing the changes made. Included source would be nice. Install package can be sent to release@whdload.de

note ~0013734 Alex C (reporter) 2024-05-29 21:50	Ok. For now ORK and Creatures I fixed some bugs. I will try to test now in a physical CD32. The person who developed this, left the code as very old. with devpac in half and half modern but. I will try to finish that ones this week. Maybe are not impressive changes but they compile and some coding is updated. Thank you

note ~0013743 Alex C (reporter) 2024-06-02 22:32	Hello again. I was exploring other release and it has bugs. Is the World Ciircuit. I want to check if I can fix. Added to the issue of NTSC it crash in AMIKIT and hundred of releases don’t crash. This one crash hard. Do you have source code for that one? Check photo of one example of crash. I think that can be integrated inside code to avoid issues. I see is from 2002 clearly needs updates. I mean this source code: http://whdload.de/games/WorldCircuit.html I tried to upload a photo but it can’t as it says PHP size not allowed. Tthen I attach here in this server: https://ibb.co/CBk4KQY

note ~0013744 Wepl (manager) 2024-06-02 22:41 Last edited: 2024-06-02 22:42 View 2 revisions	Please ask Codetapper an eab for source code, he is still active. The error picture from you is a WHDLoad problem and has nothing to do with the Slave. Probably you have NTSC option set and no NTSC monitor installed.

note ~0013755 Alex C (reporter) 2024-06-05 03:59	Thank you for the tip. Yes I contacted him and woke he is amazing. Since 90’s he still active. Definitely is a master. One more thing. I read that this one sadly the created passed and you made a memorial? That is sad really. When you hear news like this. I know it has a lot of time if is the same I speak but is sad. https://www.whdload.de/games/DickTracy.html Could you send the source for this one for last. I purchased the original and I will add more versions there. THank you for all and the support Thank you

note ~0013756 Alex C (reporter) 2024-06-05 04:21	Sorry for the confusion. Anyway, my words about the memorial are valid. All my condolences. However, I confused of Dick Tracy versions. What I have is the 3 disks versions is this one: http://www.whdload.de/games/DickTracyAdv.html Sorry for the confusion. It marks me error also.

note ~0013757 Wepl (manager) 2024-06-05 22:17	for "Dick Tracy - The Crime Solving Adventure" you may ask Cfou! he is still active

note ~0013758 Alex C (reporter) 2024-06-07 03:09	Ok. Thank you.. Do you know if for this one is active the user? Or do you have it? https://www.whdload.de/games/DojoDan.html Thank you

note ~0013759 Alex C (reporter) 2024-06-07 04:09	Also I see you created the Aladdin. Do you have that one I have my original and I removed some things and would be good try. http://www.whdload.de/download.html Another thing. The shadow of the beast 2 has some errors: error 2029 in "Beast2.s": branch destination out of range > bsr.b Patcher error 2029 in "Beast2.s": branch destination out of range > bsr.b Swap2 error 2029 in "Beast2.s": branch destination out of range > bsr.b Swap4 error 2029 in "Beast2.s": branch destination out of range > bsr.b Swap6 error 2029 in line "Beast2.s": branch destination out of range > bsr.b Swap8 The creators used ambiguos .b to call and is out of range due the distance required. Then I replaced that bsr.b to bsr.w and I’m fixing other things also. I just wanted to tell you. I’m fixing some things and in other slaves also.

note ~0013760 Alex C (reporter) 2024-06-07 04:11	Oh the link of download is my error is this one sorry my bad: http://whdload.de/games/Aladdin.html

note ~0013761 Wepl (manager) 2024-06-07 10:22	You need to ask Psygore for source, I only have older sources. For "shadow of the beast 2" just use the correct assembler options, there is no need to change anything there!

note ~0013762 Alex C (reporter) 2024-06-07 17:06	Ok I will do. Other questions. I’m trying to make some installers but to compile I need the rawdic.i where can be found? And about Dojo Dan I tried to see is an old release but is not working the contact.

note ~0013763 Wepl (manager) 2024-06-07 23:09	In the WHDLoad dev-package there is Extra/RawDIC61.lha This contains the include file for RawDIC. For DojoDan you may ask Abaddon on eab.

note ~0013767 Alex C (reporter) 2024-06-10 17:29	I could download the RawDIC include. Thank you is very good. I’m now understanding the tracks and is amazing how you defined all of the if you want, skip if they have errors. etc. I remember you have all Bored Seal. Do you have this one? https://www.whdload.de/games/MeanStreets.html What I don’t luck how to contact is Psygore for Aladdin and CFOU for Dick Tracy Adventure. Any idea? Thank you.

note ~0013768 Wepl (manager) 2024-06-10 23:23	attached. Psygore and Cfou are on eab too.

note ~0013770 Alex C (reporter) 2024-06-11 05:50	Thank you. Yes I sent message to them I will wait answer. Also for this one: https://www.whdload.de/games/Supremacy.html I tried to search Dark Angel and they site posted there and all is dead. Still exist that source in your backups?

Notes

Date Modified	Username	Field	Change
Issue History
2024-05-29 09:33	administrator	New Issue
2024-05-29 09:53	Wepl	Note Added: 0013729
2024-05-29 09:53	Wepl	Assigned To	=> Wepl
2024-05-29 09:53	Wepl	Status	new => closed
2024-05-29 09:53	Wepl	Resolution	open => no change required
2024-05-29 15:45	Alex C	Status	closed => feedback
2024-05-29 15:45	Alex C	Resolution	no change required => reopened
2024-05-29 15:45	Alex C	Note Added: 0013730
2024-05-29 15:54	Alex C	Note Added: 0013731
2024-05-29 15:54	Alex C	Status	feedback => assigned
2024-05-29 21:40	Wepl	File Added: Pitfighter.asm
2024-05-29 21:43	Wepl	Note Added: 0013733
2024-05-29 21:50	Alex C	Note Added: 0013734
2024-06-02 22:32	Alex C	Note Added: 0013743
2024-06-02 22:41	Wepl	Note Added: 0013744
2024-06-02 22:42	Wepl	Note Edited: 0013744	View Revisions
2024-06-05 03:59	Alex C	Note Added: 0013755
2024-06-05 04:21	Alex C	File Added: IMG_9644.jpeg
2024-06-05 04:21	Alex C	Note Added: 0013756
2024-06-05 22:17	Wepl	Note Added: 0013757
2024-06-07 03:09	Alex C	Note Added: 0013758
2024-06-07 04:09	Alex C	Note Added: 0013759
2024-06-07 04:11	Alex C	Note Added: 0013760
2024-06-07 10:22	Wepl	Note Added: 0013761
2024-06-07 17:06	Alex C	Note Added: 0013762
2024-06-07 23:09	Wepl	Note Added: 0013763
2024-06-10 17:29	Alex C	Note Added: 0013767
2024-06-10 23:23	Wepl	File Added: MeanStreets.asm
2024-06-10 23:23	Wepl	Note Added: 0013768
2024-06-11 05:50	Alex C	Note Added: 0013770

Issue History